Windows 10 全系激活工具纯绿色

xpower • • 原创作品, 技术文档, 软件资源 • 14536 阅读 
@rem 程序制作  By:Xpower
@rem  Windows 10全系列激活程序 无毒 无提示

@fsutil dirty query "%systemdrive%" 1>nul 2>nul || (mshta vbscript:CreateObject^("Shell.Application"^).ShellExecute^("""cmd.exe""","/c %~s0",,"runas",1^)^(window.close^)&&exit)
@fsutil dirty query "%systemdrive%" 1>nul 2>nul || goto QQ
@echo off & setlocal enabledelayedexpansion & title %~n0 & color e0 &mode con cols=65 lines=30
Rem 尝试以管理员权限运行

Rem 激活密钥
set n=10&for %%a in (

W269N-WFGWX-YVC9B-4J6C9-T83GX_Professional_10_专业版
NPPR9-FWDCX-D2C8J-H872K-2YT43_Enterprise_10_企业版
NW6C2-QMPVW-D7KKK-3GKT6-VCFB2_Education_10_教育版
NRG8B-VKK3Q-CXVCJ-9G2XF-6Q84J_ProfessionalEducation_10_专工版
6TP4R-GNPTD-KYYHQ-7B7DP-J447Y_ProfessionalWorkstation_10_专教版

WNMTR-4C88C-JK8YV-HQ7T2-76DF9_EnterpriseS_10_企长5
DCPHK-NFMTC-H88MJ-PFHPY-QJ4BJ_EnterpriseS_10_企长6
M7XTQ-FN8P6-TTKYV-9D4CC-J462D_EnterpriseS_10_企长9
YYVX9-NTFWV-6MDM3-9PT4T-4M68B_EnterpriseG_10_企业G

TX9XD-98N7V-6WMQ6-BX7FG-H8Q99_Core_10_家庭版
PVMJN-6DFY6-9CCP6-7BKTT-D3WVR_CoreCountrySpecific_10_家中版
7HNRX-D7KGG-3K4RQ-4WPJ4-YTDFH_CoreSingleLanguage_10_家单版

GCRJD-8NW9H-F2CDX-CCM8D-9D6T9_Professional_81_专业版
MHF9N-XY6XB-WVXMC-BTDCT-MKKG7_Enterprise_81_企业版
NG4HW-VH26C-733KW-K6F98-J8CK4_Professional_8_专业版
32JNW-9KQ84-P47T8-D8GGY-CWCK7_Enterprise_8_企业版

BN3D2-R7TKB-3YPBD-8DRP2-27GG4_Core_8_家庭版
4K36P-JN4VD-GDC6V-KDT89-DYFKP_CoreCountrySpecific_8_家中版
2WN2H-YGCQR-KFX6K-CD6TF-84YXQ_CoreSingleLanguage_8_家单版

FJ82H-XT6CR-J8D7P-XQJJ2-GPDD4_Professional_7_专业版
33PXH-7Y6KF-2VJC9-XBBR8-HVTHH_Enterprise_7_企业版
YFKBB-PQJJV-G996G-VWGXY-2V3X8_Business_6_商业版
VKK3X-68KWM-X2YGT-QR4M6-4BWMV_Enterprise_6_企业版
) do (set /a n+=1&for /f "tokens=1 delims=_" %%b in ("%%a") do set 密钥!n!=%%b)

Rem 激活服务器
set n=10&for %%a in (

kms.03k.org
kms.chinancce.com
kms.v0v.bid
kms.90zm.xyz
kms.loli.beer
kms.tttal.com

cy2617.jios.org
kms.lotro.cc
120.25.106.13
xykz.f3322.org
kms.luody.info
amrice.top
kms.digiboy.ir
kms.moeclub.org
kms.lolico.moe
kms8.MSGuides.com
) do (set /a n+=1&set 服务器!n!=%%a)

cls
echo.
echo        （HacKer By Xpower）
echo ===========================================================
echo  本工具支持以下版本：
echo.
echo 【Win 10 专业/企业/教育/LTSB/专工/专教/企业G】
echo.
echo 【Win 10 家庭版  /  家庭中文版  /   单语言  】
echo.
echo 【Win 8.1 专业版/企业版  Win 8 专业版/企业版】
echo.
echo 【Win 7 专业版/企业版    Vista 商用版/企业版】
echo.
echo ===========================================================

for /f "tokens=3 delims= " %%i in ('reg QUERY "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "EditionID"') do set IDD=%%i
set cs=cscript //nologo %windir%\system32\
set vee=Professional Enterprise Education ProfessionalWorkstation ProfessionalEducation
set /a 密钥=11,结束=33,n=10
TIMEOUT /T 7
ver | find "6.0." >NUL && set 密钥=32 && set 结束=33
ver | find "6.1." >NUL && set 密钥=30 && set 结束=31
ver | find "6.2." >NUL && set 密钥=23 && set 结束=29
ver | find "6.3." >NUL && set 密钥=23 && set 结束=29
ver | find "10.0." >NUL && set 密钥=11 && set 结束=22 && for %%i in (%vee%) do (set /a n+=1&if /i "!IDD!"=="%%i" (set ra=!n!&goto 10))

:101
cls&echo 激活中……
if /i "!IDD!"=="Ultimate" goto 107
(%cs%slmgr.vbs -ckms ) >nul 2>nul
goto 1

:107
%cs%slmgr.vbs -ato | find "成功" && goto 3
%cs%slmgr.vbs -ipk TFP9Y-VCY3P-VVH3T-8XXCC-MF4YK & %cs%slmgr.vbs -ato | find "成功" && goto 3
%cs%slmgr.vbs -ipk RHTBY-VWY6D-QJRJ9-JGQ3X-Q2289 & %cs%slmgr.vbs -ato | find "成功" && goto 3
goto Q


:10
echo.
echo [专业版按1]       [企业版按2]       [教育版按3]
echo [专业工作站按4]       [专业教育版按5]
echo [自动选择按0]
CHOICE /C 123450 /N /T 6 /D 0 /M "请输入序号："
(
if "%errorlevel%"=="1" set ra=%密钥11%
if "%errorlevel%"=="2" set ra=%密钥12%
if "%errorlevel%"=="3" set ra=%密钥13%
if "%errorlevel%"=="4" set ra=%密钥14%
if "%errorlevel%"=="5" set ra=%密钥15%
if "%errorlevel%"=="6" set ra=!密钥%ra%!
)
cls&echo 激活中……
%cs%slmgr.vbs -ipk !ra! | find "成功" && goto 2
echo 选择的版本无效。已切换为自动选择密钥。
goto 1

:1
for /L %%a in (%密钥%,1,%结束%) do (%cs%slmgr.vbs -ipk !密钥%%a! | find "成功" && goto 2 )
set err=1
goto Q

:2
for /L %%a in (11,1,16) do (%cs%slmgr.vbs -skms !服务器%%a! & %cs%slmgr.vbs -ato | find "成功" && goto 3 )
ping -n 1 www.qq.com -w 3000 | find /i "TTL" >nul&&(set err=2&goto Q)
ping -n 1 www.baidu.com -w 3000 | find /i "TTL" >nul&&(set err=2&goto Q)
set err=3
goto Q

:3
color 9F
echo+ & echo 恭喜！激活成功！
echo       请保留本文件以后还可以激活
echo+ 
goto Q

:Q
%cs%slmgr.vbs -ato

if "%err%"=="1" (color 4F&echo 错误：激活失败。
ver
wmic os get caption
echo !IDD!--%PROCESSOR_ARCHITECTURE%--%USERNAME%--3.3c
echo       激活失败 联系QQ49182948
echo.
if /i "!IDD!"=="Ultimate" (echo 本工具不支持激活Win7旗舰版！请换企业版，或尝试电话激活。&slui 4)
if /i "!IDD!"=="EnterpriseEval" echo 您使用的是企业评估试用版，请先转为企业正式版再激活。
for %%i in (%vee% Core CoreCountrySpecific) do if /i "!IDD!"=="%%i" (echo 环境异常。需重启电脑后再试。 & echo 按任意键立即重启 & pause>nul & shutdown /r /f /t 2 & TIMEOUT /T 10 >nul )
)

if "%err%"=="2" (color 4F
echo 错误：KMS服务不可用
echo 您的系统激活组件不全或已损坏
echo 建议去微软官网下载 安装/修复Win10工具
echo 稍后弹出网页后，点击“立即下载工具”
echo 一路下一步即可修复
echo 修复时间不同电脑配置有所不同
echo 可能需要半小时或两三个小时
echo 修复操作不会删除您的任何文件和程序
echo 尽管放心。如修复程序要求输入密钥
echo NW6C2-QMPVW-D7KKK-3GKT6-VCFB2
TIMEOUT /T 9 >nul
start "" "https://www.microsoft.com/zh-cn/software-download/windows10/"
)

if "%err%"=="3" (color 4F&echo 错误：您没有连接互联网？~试试本地激活工具吧
)

echo 按任意键退出。 & pause>nul
exit

:QQ
color 4f
echo 请右键“以管理员身份运行”
TIMEOUT /T 3 >nul
2>nul md %temp%\tem101
copy /y "%~0" "%temp%\tem101\【选中文件 右键】以管理员身份运行.bat"&&start "" "%temp%\tem101"
TIMEOUT /T 7 >nul
exit

===========================================================
本工具支持以下版本：

【Win 10 专业/企业/教育/LTSB/专工/专教/企业G】

【Win 10 家庭版 / 家庭中文版 / 单语言 】

【Win 8.1 专业版/企业版 Win 8 专业版/企业版】

【Win 7 专业版/企业版 Vista 商用版/企业版】

复制新建文本文档，修改名字为bat 使用右键管理员运行，win10 通杀

懒人下载地址：

资源文件下载
来源：默认网盘
THE END
分享
二维码
< <上一篇
下一篇>>